
**** 01/29/14 00:35:27 ********* PSpice 9.2 (Mar 2000) ******** ID# 1 ********

  


 ****     CIRCUIT DESCRIPTION


******************************************************************************



***** Mod L based on Xmeh_Electrical processes.

***** Sources of the information:


* 1. File "d:\Documents_Glebov\Magnetic materials and cores\Texts, Tables, Modeling\
*           \Modelirovanie processov peremagnichivanija ferromagnttikov_fin.doc".
* 2. File "d:\PSpice-modelling\Typical schemes and models\Macromodels by Glebov\Macromodels of magnetic elements\Circutry\
*          \PSpice model Xmeh.doc".
* 3. File "d:\PSpice-modelling\Typical schemes and models\Macromodels by Glebov\Macromodels of magnetic elements\
*          \The calculations of the model parameters.mcd".
* 4. V.D. Razevig. Sistema proektirovanija OrCad 9.2" Moskva "SOLON-R, 2001. 519 str, ill.
* 5. File "d:\PSpice-modelling\Typical schemes and models\Macromodels by Glebov\Macromodels of magnetic elements\
*           \Creating a model Xmeh\Model Xmeh_Electrical processes.cir".


******************************************************** 

***** The list of parameters of the pulses applied to the coil of the magnetic element. 

* f - frequency;
* Dtop - the duration top of the pulse, expressed in relative units;
* td1 - delay of the first pulse relative to the beginning period of work;
* td2 - delay of the second pulse relative to the beginning period of work;
* tr - pulse rise time;
* tf - pulse fall time;
* Tt - the duration top of the pulse, expressed in absolute units;
* T - period.


*** The values of the varied parameters of the pulse generator.

.Param f=100k
.Param Dtop=0.8
.Param Td1=200n
.Param Tr=20n
.Param Tf=20n
.Param T={1/f}
.Param Td2={(T/2)+Td1}
.Param Ttop={(Dtop*(T/2)-(Td1+Tr+Tf))}

.Param Vmax=100


*** The number of turns the coil inductor L1.

.Param wL1=8

***** The pulse generator and circuits connected to the generator.
 
V1 g1 0 pulse (0 {Vmax} {Td1} {Tr} {Tf} {Ttop} {T})
V2 g2 0 pulse (0 {-Vmax} {Td2} {Tr} {Tf} {Ttop} {T})

Eg 1 3 Value={V(g1)+V(g2)}

Ris 3 0 1e6


*** Resistance of the coil of the inductor L1.

RL1 1 2 100m


*** Winding inductance of the inductor L1.

L1 2 3 4.8E-6 IC=0


*** Dependent current source magnetization equal magnetomotive force produced in the core of the inductor L1 its winding current, di

G_XL1 3 4 Value={wL1*I(L1)}


*** The current sensor that shows magnetic heat loss. 

Vi_XL1 5 3 dc 0


*** The model of inductor L1

XL1 2 3 4 5 Xmeh

+ PARAMS: Lmag=7.5E-8 Ku=0.966 w={wL1} 

+ Fso=1.329E+3 Kso=2 Fs=948.736 Ks=6

+ Lh=1.551E-3 Ih=36.733 Kh=2

+ Rdyn=8.786k Fd=133.416 Kd=2


********************************************

.SUBCKT Xmeh 1 2 3 4

+ PARAMS: Lmag=7.5E-8 Ku=0.966 w=8 

+ Fso=1.329E+3 Kso=2 Fs=948.736 Ks=6

+ Lh=1.551E-3 Ih=36.733 Kh=2

+ Rdyn=8.786k Fd=133.416 Kd=2

*****

Vi_m 3 2 dc 0

Gs 1 2 Value={Ku*(I(Vi_m)/w)*(PWR({I(Vi_m)/Fso}, Kso)+PWR({I(Vi_m)/Fs}, Ks))}

Rd 1 5 {Rdyn} 

Vi_Rd 5 4 dc 0

Gd 1 4 Value={(I(Vi_Rd))*(PWR(I(Vi_m)/Fd, Kd))}

Em 6 2 Value={V(1, 2)}

Dp 6 7 Dsf

Lp 7 8 {Lh}

Ep 2 8 Value={1e4*(V(1, 2)-ABS(V(1, 2)))}

Dn 9 6 Dsf

Ln 9 10 {Lh}

En 2 10 Value={1e4*(V(1, 2)+ABS(V(1, 2)))}

Gh 2 4 Value={(I(Lp)*(1+(PWR(I(Lp)/Ih, Kh)))+I(Ln)*(1+(PWR(I(Ln)/Ih, Kh))))}

***

.model Dsf D (Rs=1u Cjo=0 Tt=0 Is=1u)

*****

.ENDS Xmeh


********************************************************

.Option StepGmin ITL4=1000 ABSTOL=1m VnTOL=1m

********************************************************
.tran 10n 400u 280u 10n uic
.probe
.end 

**** 01/29/14 00:35:27 ********* PSpice 9.2 (Mar 2000) ******** ID# 1 ********

  


 ****     Diode MODEL PARAMETERS


******************************************************************************




               XL1.Dsf         
          IS    1.000000E-06 
          RS    1.000000E-06 



          JOB CONCLUDED

          TOTAL JOB TIME            1.77
