
**** 11/02/13 06:57:00 ********* PSpice 9.2 (Mar 2000) ******** ID# 1 ********

  


 ****     CIRCUIT DESCRIPTION


******************************************************************************



***** Macromodel Xmh of magnetic elements.

***** Sources of the information:

* 1. File "d:\Documents_Glebov\Magnetic materials and cores\Texts, Tables, Modeling\
*           \Modelirovanie processov peremagnichivanija ferromagnttikov_fin.doc".
* 2. File "d:\PSpice-modelling\Typical schemes and models\Macromodels by Glebov\Macromodels of magnetic elements\Circutry\
*          \PSpice model Xmeh.doc".
* 3. File "d:\PSpice-modelling\Typical schemes and models\Macromodels by Glebov\Macromodels of magnetic elements\
*          \The calculations of the model parameters.mcd".
* 4. V.D. Razevig. Sistema proektirovanija OrCad 9.2" Moskva "SOLON-R, 2001. 519 str, ill.


******************************************************** 

***** The list of parameters of the pulses applied to the coil of the magnetic element. 

* f - frequency;
* Dtop - the duration top of the pulse, expressed in relative units;
* td1 - delay of the first pulse relative to the beginning period of work;
* td2 - delay of the second pulse relative to the beginning period of work;
* tr - pulse rise time;
* tf - pulse fall time;
* Tt - the duration top of the pulse, expressed in absolute units;
* T - period.


*** The values of the varied parameters of the pulse generator.


.Param f=100k
.Param Dtop=0.8
.Param Td1=200n
.Param Tr=20n
.Param Tf=20n
.Param T={1/f}
.Param Td2={(T/2)+Td1}
.Param Ttop={(Dtop*(T/2)-(Td1+Tr+Tf))}

.Param Vmax=100


***** Values of the varied parameters of the model of the magnetic element [3].


.Param Lmag=7.5E-8
.Param Lu=7.765E-8
.Param Ku={Lmag/Lu}
.Param w=8

.Param Fso=1.329E+3
.Param Kso=2
.Param Fs=948.736
.Param Ks=6

.Param Lh=1.551E-3
.Param Ih=36.733
.Param Kh=2

.Param Rdyn=8.786E+3
.Param Fd=133.416
.Param Kd=2




***** The pulse generator and circuits connected to the generator.
 
V1 g1 0 pulse (0 {Vmax} {Td1} {Tr} {Tf} {Ttop} {T})
V2 g2 0 pulse (0 {-Vmax} {Td2} {Tr} {Tf} {Ttop} {T})

Ris 2 0 1000k

Eg g 2 Value={V(g1)+V(g2)}


*** Resistance of the coil of the magnetic element.

Rw g 1 100m


*** Winding inductance of the magnetic element.

L 1 2 4.8u ic=0


*** Dependent current source magnetization equal magnetomotive force produced in the core of the magnetic element its winding curren

G_X 2 3 Value={w*I(L)}


*** The current sensor that shows magnetic heat loss. 

Vi_X 4 2 dc 0


***** Internal circuits macromodel ferromagnetic core with winding WL.


*** Current sensor magnetization.

Vi_m 3 2 dc 0


*** Dependent current source, showing non-linear magnetic characteristics of the core.

Gs 1 2 Value={Ku*(I(Vi_m)/w)*(PWR({I(Vi_m)/Fso}, Kso)+PWR({I(Vi_m)/Fs}, Ks))}


*** Circuits, showing the dynamic processes in the reversal of the core.

Rd 1 5 {Rdyn} 

Vi_Rd 5 4 dc 0

Gd 1 4 Value={(I(Vi_Rd))*(PWR(I(Vi_m)/Fd, Kd))}


*** Dependent source voltage is equal to the electromotive force of an electromagnetic induction coil WL.

Em 6 2 Value={V(1, 2)}


*** Electrical circuit to form a rising (positive) branch of the hysteresis characteristics.

Dp 6 7 Dsf

Lp 7 8 {Lh}

Ep 2 8 Value={1e4*(V(1, 2)-ABS(V(1, 2)))}


*** Electrical circuit to form a downward (negative) branch of the hysteresis characteristics.

Dn 9 6 Dsf

Ln 9 10 {Lh}

En 2 10 Value={1e4*(V(1, 2)+ABS(V(1, 2)))}


*** Electrical circuit to form the nonlinear component of hysteresis characteristics of ferromagnetic core.

Gh 2 4 Value={(I(Lp)*(1+(PWR(I(Lp)/Ih, Kh)))+I(Ln)*(1+(PWR(I(Ln)/Ih, Kh))))}


***

.model Dsf D (Rs=1u Cjo=0 Tt=0 Is=1u)


********************************************************

.Option StepGmin ITL4=1000 ABSTOL=1m VnTOL=1m

********************************************************
.tran 5n 400u 380u 5n uic
.probe
.end 

**** 11/02/13 06:57:00 ********* PSpice 9.2 (Mar 2000) ******** ID# 1 ********

  


 ****     Diode MODEL PARAMETERS


******************************************************************************




               Dsf             
          IS    1.000000E-06 
          RS    1.000000E-06 



          JOB CONCLUDED

          TOTAL JOB TIME            3.55
